// TOWN DIALOGUE SCRIPT
//    Town 0: Cresent Tail

// This is the dialogue for this town.
// You can use states numbered from 1 to 99.

begintalkscript;

variables;

short choice;

// *** Fido ***
begintalknode 1;
	state = -1;
	nextstate = -1;
	condition = 1;
	question = "Fido";
	text1 = "Fido goes _woof_ as you try to talk to him.";
	text2 = "He ignores your questioning and goes _woof_ again.";
	action = END_TALK;

begintalknode 2;
	state = -1;
	nextstate = -1;
	condition = 1;
	question = "Frisky";
	text1 = "Frisky plays with your hand and goes _meow_ as you try to talk to her.";
	text2 = "For some reason, she doesn't answer your question, but goes _meow_ again.";
	action = END_TALK;

// *** (Stinky) Pete ***
begintalknode 5;
	state = -1;
	personality = 11;
	nextstate = 6;
	condition = 1;
	question = "Pete";
	text1 = "A rough looking (and very smelly) man is busy cleaning fish behind the counter.";
	text2 = "He looks up smiling as he cleans his hands off with a dirty towel and extends them in greeting.";
	text3 = "_Hello travelers, I'm Pete, do you want to look at my catch?_";
	text4 = "You are thinking, based on the smell, that 'Stinky Pete' is more appropriate.";
	text5 = "Pete quickly wipes off his hands on his dirty towel and starts shaking yours in greeting.";
	text6 = "_Hello again, got a fresh catch for you to look over._";
	action = INTRO;

begintalknode 6;
	state = 6;
	personality = 11;
	nextstate = -1;
	condition = 1;
	question = "What do you do?";
	text1 = "_I catch fish to sell to travelers going through._";
	text2 = "_Unfortunately, with the she-devil around, there aren't very many people traveling around._";
	text3 = "_Would you like to see my fresh catch?_ he asks";

begintalknode 7;
	state = 6;
	personality = 11;
	nextstate = -1;
	condition = 1;
	question = "What do you know about the she-devil?";
	text1 = "_Can't tell you much.  Never ran into her._";
	text2 = "_Some folks around here are scared though._";
	text3 = "_People in Cresent Harbor, to the east of here, might know more though._";
	text4 = "_Can I interest you in some fresh seafood?_";

begintalknode 8;
	state = 6;
	personality = 11;
	nextstate = -1;
	condition = 1;
	question = "Can I look at your fresh catch?";
	text1 = "You finish purchasing Stinky Pete's seafood.";
	action = END_TALK;
	code =
		begin_shop_mode("Stinky Pete's Fish", "Pete is a fisherman who offers a variety of fresh catch to a hungry traveller.  The prices are extremely cheap.", 8, 0, -1);
	break;

// *** Jane ***
begintalknode 15;
	state = -1;
	personality = 13;
	nextstate = 16;
	condition = 1;
	question = "Jane";
	text1 = "A very beautiful blond woman is pacing around inside of the house.";
	text2 = "She seems startled by your intrusion, but collects herself together quickly.";
	text3 = "_Hi.  I am Jane.  What are you doing in my house?_";
	text5 = "Jane looks up at you when you approach her.";
	text6 = "_What do you want?_ she asks.";
	action = INTRO;

begintalknode 16;
	state = 16;
	personality = 13;
	nextstate = 17;
	condition = get_flag(50, 2) == 0;
	question = "What do you do?";
	text1 = "_I recently lost my husband to that infernal she-devil._";
	text2 = "She adds _To compound the loss, I lost the bracelet he gave me._";
	text3 = "She seems a little sad about the loss.";

begintalknode 17;
	state = 16;
	personality = 13;
	nextstate = 17;
	condition = (get_flag(50, 2) > 0) && (get_flag(50, 3) == 0) && (has_special_item(2) == 0);
	question = "I haven't found the bracelet yet.";
	text1 = "Jane looks peeved _What are you doing here then?_";

begintalknode 18;
	state = 16;
	personality = 13;
	nextstate = -1;
	condition = (get_flag(50, 2) > 0) && (has_special_item(2) > 0);
	question = "I have found your bracelet.";
	text1 = "Jane gets joyful and kisses each of you as you hand the bracelet to her.";
	text2 = "_Thank you for returning this to me.  I can't afford much but accept this purse of coins._";
	text3 = "Jane hands you a small purse of coins.  You thank her and leave her to her thoughts";
	action = END_TALK;
	code =
		take_special_item(2);
		set_flag(50, 3, 1);
		toggle_quest(1, 0);
		play_sound(39);
		pay_coins(100);
		award_party_xp(20, 15);
	break;

begintalknode 19;
	state = 16;
	personality = 13;
	nextstate = 17;
	condition = get_flag(50, 3) > 0;
	question = "Hello again.";
	text1 = "_Thank you for finding my bracelet, but I'd perfer to be left alone._";
	text2 = "Jane continues to pace, trying to ignore you.";

begintalknode 20;
	state = 16;
	personality = 13;
	nextstate = -1;
	condition = 1;
	question = "Sorry to bother you, bye.";
	text1 = "Jane goes back to pacing around the house.";
	action = END_TALK;

begintalknode 21;
	state = 17;
	personality = 13;
	nextstate = -1;
	condition = 1;
	question = "What do you know about the she-devil?";
	text1 = "Jane replies _Not much, just that it seems to kill most who get in her path._";
	text2 = "_No one knows what her purpose is or where she came from._";
	text3 = "_She got my husband when he followed her east of Cresent Harbor.  Of course it was his own fault for doing so._";
	text4 = "_I'd be careful if you are thinking about doing something about her._ Jane says worriedly";
	text5 = "Jane then adds _People in Cresent Harbor will know more about her since the empire garrison is stationed there._";

begintalknode 22;
	state = 17;
	personality = 13;
	nextstate = -1;
	condition = get_flag(50, 2) == 0;
	question = "I will find your bracelet for you.";
	text1 = "Jane gives you a smile and says _Thank you_.";
	text2 = "_I lost in a crack of a big rock to the west of town when I was surprised by a big worm like creature._";
	text3 = "_I can't offer much but some money I have saved if you can retrieve it for me._";
	text4 = "Jane goes back to pacing around the house seemingly lost in thought.";
	action = END_TALK;
	code =
		set_flag(50, 2, 1);
		toggle_quest(1, 1);
	break;

begintalknode 23;
	state = 17;
	personality = 13;
	nextstate = -1;
	condition = 1;
	question = "Sorry to hear about that, bye.";
	text1 = "Jane looks at you briefly, then ignores you.";
	action = END_TALK;
